[Build-System] Remove Sofia-Sip library from the FreeSWITCH tree and use packages instead.

build/config/sac-openssl.m4

@@ -0,0 +1,49 @@
+dnl ======================================================================
+dnl SAC_OPENSSL
+dnl ======================================================================
+AC_DEFUN([SAC_OPENSSL], [
+
+AC_ARG_WITH(openssl,
+[  --with-openssl          use OpenSSL [[enabled]]],, with_openssl=pkg-config)
+
+dnl SOSXXX:SAC_ASSERT_DEF([openssl libraries])
+
+
+if test "$with_openssl" = no  ;then
+  : # No openssl
+else
+
+  if test "$with_openssl" = "pkg-config" ; then
+    PKG_CHECK_MODULES(openssl, openssl,
+	[HAVE_TLS=1 HAVE_OPENSSL=1 LIBS="$openssl_LIBS $LIBS"],
+	[HAVE_OPENSSL=0])
+  fi
+
+  if test x$HAVE_OPENSSL = x1 ; then
+     AC_DEFINE([HAVE_LIBCRYPTO], 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
+     AC_DEFINE([HAVE_LIBSSL], 1, [Define to 1 if you have the `ssl' library (-lssl).])
+  else
+    AC_CHECK_HEADERS([openssl/tls1.h], [
+      HAVE_OPENSSL=1 HAVE_TLS=1
+
+      AC_CHECK_LIB(crypto, BIO_new,,
+      	HAVE_OPENSSL=0
+      	AC_MSG_WARN(OpenSSL crypto library was not found))
+
+      AC_CHECK_LIB(ssl, TLSv1_method,,
+      	HAVE_TLS=0
+      	AC_MSG_WARN(OpenSSL protocol library was not found))
+     ],[AC_MSG_WARN(OpenSSL include files were not found)],[#include <openssl/safestack.h>])
+  fi
+
+  if test x$HAVE_OPENSSL = x1; then
+     AC_DEFINE([HAVE_OPENSSL], 1, [Define to 1 if you have OpenSSL])
+  fi
+
+  if test x$HAVE_TLS = x1; then
+    AC_DEFINE([HAVE_TLS], 1, [Define to 1 if you have TLS])
+  fi
+fi
+
+AM_CONDITIONAL(HAVE_TLS, test x$HAVE_TLS = x1)
+])

build/config/sac-pkg-config.m4

@@ -0,0 +1,56 @@
+dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
+dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
+dnl also defines GSTUFF_PKG_ERRORS on error
+AC_DEFUN([PKG_CHECK_MODULES], [
+  succeeded=no
+
+  if test -z "$PKG_CONFIG"; then
+    AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
+  fi
+
+  if test "$PKG_CONFIG" = "no" ; then
+     echo "*** The pkg-config script could not be found. Make sure it is"
+     echo "*** in your path, or set the PKG_CONFIG environment variable"
+     echo "*** to the full path to pkg-config."
+     echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
+  else
+     PKG_CONFIG_MIN_VERSION=0.9.0
+     if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
+        AC_MSG_CHECKING(for $2)
+
+        if $PKG_CONFIG --exists "$2" ; then
+            AC_MSG_RESULT(yes)
+            succeeded=yes
+
+            AC_MSG_CHECKING($1_CFLAGS)
+            $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
+            AC_MSG_RESULT($$1_CFLAGS)
+
+            AC_MSG_CHECKING($1_LIBS)
+            $1_LIBS=`$PKG_CONFIG --libs "$2"`
+            AC_MSG_RESULT($$1_LIBS)
+        else
+            $1_CFLAGS=""
+            $1_LIBS=""
+            ## If we have a custom action on failure, don't print errors, but 
+            ## do set a variable so people can do so.
+            $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
+            ifelse([$4], ,echo $$1_PKG_ERRORS,)
+        fi
+
+        AC_SUBST($1_CFLAGS)
+        AC_SUBST($1_LIBS)
+     else
+        echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
+        echo "*** See http://www.freedesktop.org/software/pkgconfig"
+     fi
+  fi
+
+  if test $succeeded = yes; then
+     ifelse([$3], , :, [$3])
+  else
+     ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
+  fi
+])
+
+